问题

什么样的钩子脚本是人们使用的Subversion?只是一般的想法,但代码也很棒!

  最佳答案

我正在使用pre-revprop-change钩子,允许在执行提交后实际返回并编辑注释和此类信息.如果提交注释中缺少/错误信息,这是非常有用的.

这里我为Windows NT或以后发布pre-revprop-change.bat批处理文件... 当然可以通过更多的修改来加强它。 post-revprop-change.cmd从它备份旧的snv:log在某处或只是将其附加到新的日志...

唯一棘手的部分是能够实际解析stdin 批处理文件...这是用FIND.EXE命令完成的.

另一个是,我从其他用户收到了使用/bexit命令的问题报告.如果错误案例行为不好,您可能需要在特定应用程序中删除/b.

 @ECHO OFF

set repos=%1
set rev=%2
set user=%3
set propname=%4
set action=%5

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Only allow changes to svn:log. The author, date and other revision
:: properties cannot be changed
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
if /I not '%propname%'=='svn:log' goto ERROR_PROPNAME

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Only allow modifications to svn:log (no addition/overwrite or deletion)
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
if /I not '%action%'=='M' goto ERROR_ACTION

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Make sure that the new svn:log message contains some text.
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
 set bIsEmpty=false
)
if '%bIsEmpty%'=='true' goto ERROR_EMPTY

goto :eof



:ERROR_EMPTY
echo Empty svn:log properties are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1 
 

  相同标签的其他问题

svnversion-controlscriptingsvn-hooks